home *** CD-ROM | disk | FTP | other *** search
/ HamCall (October 1991) / HamCall (Whitehall Publishing)(1991).bin / bcast / fccrf / amda1.bas (.txt) < prev    next >
ST Writer Document  |  1990-10-14  |  10KB  |  241 lines
  1. Do Run Run STWRITER.PRG
  2. 10 PRINT"     5. POLAR TO RECTANGULAR CONVERSION."
  3. 20 REM CLS
  4. 30 REM DAVE RILEY  8-87  AM DIRECTIONAL ARRAY HELPER
  5. 40 REM 11 WALNUT STREET MARSHFIELD, MA. 02050
  6. 50 REM RBBS 1200/2400 24/HRS  617-837-2880
  7. 60 PRINT:PRINT
  8. 70 PRINT TAB(10)"AM DIRECTIONAL ARRAY HELPER...DAVE RILEY...8-87"
  9. 80 PRINT TAB(10)"RBBS-DATA 1200/2400 BAUD 24/HRS  617-837-2880
  10. 90 PRINT:PRINT
  11. 100 PRINT"     1. T NETWORK 90 DEGREES, INPUT R1-R2"
  12. 110 PRINT"     2. T NETWORK OTHER THAN 90 DEGREES AND 50 OHMS IN/OUT"
  13. 120 PRINT"     3. T NETWORK OTHER THAN 90 DEGREES, INPUT R1-R2"
  14. 130 PRINT"     4. SERIES NETWORK PHASE ANGLE"
  15. 140 PRINT"     5. POLAR TO RECTANGULAR CONVERSION"
  16. 150 PRINT"     6. RECTANGULAR TO POLAR CONVERSION"
  17. 160 PRINT"     7. L/C RESONANT FREQUENCY"
  18. 170 PRINT"     8. SPACE PHASE"
  19. 180 PRINT"     9. RADIAL FIELD VECTORS"
  20. 190 PRINT
  21. 200 PRINT"     X. >>>> RETURN TO DOS <<<<":PRINT:PRINT
  22. 210 PRINT"          SELECT # ITEM ABOVE for COMPUTATION"
  23. 220 I$=INKEY$: IF I$="" THEN 220
  24. 230 REM  select program start line
  25. 240 IF I$="1" THEN 440
  26. 250 IF I$="2" THEN 550
  27. 260 IF I$="3" THEN 690
  28. 270 IF I$="4" THEN 860
  29. 280 IF I$="5" THEN 1000
  30. 290 IF I$="6" THEN 1140
  31. 300 IF I$="7" THEN 1270
  32. 310 IF I$="8" THEN 1370
  33. 320 IF I$-"9" THEN 1770
  34. 330 IF I$="X" THEN SYSTEM
  35. 340 IF I$="x" THEN SYSTEM
  36. 350 GOTO 210
  37. 360 PRINT"                         RE-CALCULATE SAME  ?"
  38. 370 PRINT
  39. 380 PRINT"                 Y=YES    OR ANY OTHER KEY TO MENU"
  40. 390 C$=INKEY$ : IF C$="" THEN 390
  41. 400 IF C$="y" THEN RETURN
  42. 410 IF C$="Y" THEN RETURN
  43. 420 IF C$="X" THEN SYSTEM
  44. 430 GOTO 20
  45. 440 REM CLS : T Network where angle is 90 degrees and input R1 R2
  46. 450 REM  X1=X2=X3=SQR(R1*R2)
  47. 460 PRINT : PRINT
  48. 470 PRINT"             FOR A TEE NETWORK OF 90 DEGREES WITH:":PRINT
  49. 480 INPUT "                 INPUT    R-Line";R1
  50. 490 INPUT "                 INPUT    R-Load";R2
  51. 500 PRINT
  52. 510 X=SQR (R1*R2)
  53. 520 PRINT "                  X1=X2=X3=";X;"Ohms Reactive"
  54. 530 PRINT : PRINT
  55. 540 GOSUB 360 : PRINT:GOTO 440
  56. 550 REM  CLS
  57. 560 PRINT:PRINT
  58. 570 REMBER T Network where angle other than 90 degrees, R1 R2 = 50 Ohms
  59. 580 PRINT:PRINT"  FOR A TEE NETWORK OTHER THAN 90 DEGREES AND 50 OHMS IN/OUT"
  60. 590 PRINT
  61. 600 INPUT "           INPUT    Desired Phase Angle ";T:PRINT
  62. 610 F=.017453
  63. 620 R=F*T
  64. 630 X1=(50*(1-COS(R)))/(SIN(R))
  65. 640 X3=50/(SIN(R))
  66. 650 PRINT "                Series X1=X2=";X1;"Ohms Reactive"
  67. 660 PRINT "                  Shunt X=";X3;"Ohms Reactive"
  68. 670 PRINT:PRINT
  69. 680 GOSUB 360 :PRINT:GOTO 550
  70. 690 REM CLS
  71. 700 REM T Network where angle is other than 90 degrees, input R1 R2
  72. 710 PRINT:PRINT
  73. 720 PRINT"TEE NETWORK WITH SHIFT OTHER THAN 90 DEGS. AND INPUT Rin/Rout":PRINT
  74. 730 INPUT "                       Phase Angle Desired";T
  75. 740 INPUT "                       Input Resistance";R1
  76. 750 INPUT "                       Output Resistance";R2
  77. 760 F=.017453:PRINT
  78. 770 R=F*T
  79. 780 X1=((SQR(R1*R2))*(1-((R1/R2)*COS(R))))/(SIN(R))
  80. 790 X2=((SQR(R1*R2))*(1-((R2
  81. R1)*COS(R))))/(SIN(R))
  82. 800 X3=(SQR(R1*R2))/(SIN(R))
  83. 810 PRINT"                            X1=";X1
  84. 820 PRINT"                            X2=";X2
  85. 830 PRINT"                            X3=";X3
  86. 840 PRINT:PRINT
  87. 850 GOSUB 360 :PRINT:GOTO 690
  88. 860 PRINT:PRINTL:REM CLS TOO
  89. 870 REM SERIES NET Near 0 degree phase shift
  90. 880 REM Tan Theta = X/R = reactance/resistance
  91. 890 PRINT
  92. 900 PRINT"        FOR A SERIES SHIFT NETWORK NEAR ZERO DEGREES:":PRINT
  93. 910 PRINT
  94. 920 INPUT"                      Resistance of Series Load";R1
  95. 930 INPUT"                      NET Reactance of Series Network";X
  96. 940 PRINT
  97. 950 T=-X/R1
  98. 960 D=((TAN(T))*57.3)
  99. 970 PRINT "                      Phase Angle =";D
  100. 980 PRINT:PRINT
  101. 990 GOSUB 360:PRINT:GOTO 860
  102. 1000 REM CLS
  103. 1010 REM DAVE RILEY  MARSHFIELD, MASS.  DATA 617-837-2880
  104. 1020 REM POLAR TO RECTANGULAR
  105. 1030 A=1.745329E-02:PRINT:PRINT:PRINT
  106. 1040 PRINT"          POLAR INPUT TO RECTANGULAR OUTPUT:":PRINT
  107. 1050 INPUT"                           MAGNITUDE";L
  108. 1060 INPUT"                           ANGLE  ";D
  109. 1070 PRINT
  110. 1080 X=(L*COS(D*A))
  111. 1090 Y=(L*SIN(D*A))
  112. 1100 PRINT "                           X= "USING "+###.##";X
  113. 1110 PRINT "                           Y= "USING "+###.##";Y
  114. 1120 PRINT:PRINT
  115. 1130 GOSUB 360:PRINT:GOTO 1000
  116. 1140 REM CLS
  117. 1150 REM DAVE RILEY  MARSHFIELD, MASS.  DATA 617-837-2880
  118. 1160 REM RECTANGULAR TO POLAR
  119. 1170 AA=57.29583:PRINT:PRINT
  120. 1180 PRINT"      RECTANGULAR INPUT FOR POLAR OUTPUT:":PRINT
  121. 1190 INPUT"                          X VALUE ";X
  122. 1200 INPUT"                          Y VALUE ";Y
  123. 1210 M=SQR((X*X)+(Y*Y))
  124. 1220 D=(ATN(Y/X))*AA
  125. 1230 PRINT
  126. 1240 PRINT "                          MAGNITUDE = "USING "+##.#";M
  127. 1250 PRINT "                          ANGLE   =   "USING "+###.#";D
  128. 1260 PRINT:GOSUB 360:PRINT:GOTO 1140
  129. 1270 PRINT:PRINT:REM CLS
  130. 1280 REM DAVE RILEY  MARSHFIELD, MASS.  DATA 617-837-2880
  131. 1290 REM RESONANT FREQUENCY OF L AND C
  132. 1300 INPUT "                  INDUCTANCE IN MICROHENRIES";L
  133. 1310 INPUT "                  CAPACITANCE IN PICOFARADS ";C
  134. 1320 F=1/(6.28318*(SQR(L*C)))
  135. 1330 PRINT
  136. 1340 PRINT"                   FREQUENCY IN MHZ ="USING "###.##";F/.001
  137. 1350 PRINT
  138. 1360 GOSUB 360:PRINT:GOTO 1270
  139. 1370 REM CLS
  140. 1380 REM DAVE RILEY  MARSHFIELD, MASS.  DATA 617-837-2880
  141. 1390 REM SPACE PHASE ROUTINE UP TO FOUR TOWERS
  142. 1400 REM CHANGE LINES STARTING WITH SA= SB= ETC. TO YOUR OWN PARAMETERS
  143. 1410 REM FIRST NUMBER IS DISTANCE IN DEGREES FROM REFERENCE CENTER OF ARRAY TO
  144. 1420 REM TOWER. SECOND NUMBER ON LINE IS AZIMUTH FROM CENTER REFERENCE THROUGH
  145. 1430 REM THAT TOWER. SA=TOWER #1  SB=TOWER #2 ETC.
  146. 1440 KA=.017453: KB=57.29583:REM RADIAN/DEGREE CONVERSIONS
  147. 1450 PRINT:PRINT:PRINT
  148. 1460 INPUT "              TOWER #1 PHASE";A
  149. 1470 INPUT "              TOWER #2 PHASE";B
  150. 1480 INPUT "              TOWER #3 PHASE";C
  151. 1490 INPUT "              TOWER #4 PHASE";D:PRINT
  152. 1500 INPUT "              TOWER #1 FIELD";E
  153. 1510 INPUT "              TOWER #2 FIELD";F
  154. 1520 INPUT "              TOWER #3 FIELD";G
  155. 1530 INPUT "              TOWER #4 FIELD";H
  156. 1540 PRINT:PRINT
  157. 1550 INPUT "              MONITOR POINT RADIAL";M:REM CLS HERE
  158. 1560 SA=((150*KA)*COS((130-M)*KA))*KB:REM 150=DEGREES SPACE FROM ARRAY CENTER
  159. 1570 SB=((50*KA)*COS((130-M)*KA))*KB:REM 130=DEGREES HEAD FROM CENTER-TOWER
  160. 1580 SC=((50*KA)*COS((310-M)*KA))*KB
  161. 1590 SD=((150*KA)*COS((310-M)*KA))*KB
  162. 1600 PRINT"                  MONITOR RADIAL   "M" DEGREES"
  163. 1610 PRINT"                  ------------------------------":PRINT
  164. 1620 PRINT"TOWER PHASE       "USING "+###.#    "; A;B;C;D
  165. 1630 PRINT"SPACE PHASE       "USING "+###.#    "; SA;SB;SC;SD
  166. 1640 VA=SA+A : VB=SB+B : VC=SC+C : VD=SD+D
  167. 1650 PRINT"VECTOR PHASE      "USING "+###.#    "; VA;VB;VC;VD
  168. 1660 PRINT"VECTOR LENGTH     "USING "##.###    "; E;F;G;H
  169. 1670 REM POLAR TO RECT. CONVERSION X4
  170. 1680 XA=E*(COS(VA*KA)):YA=E*(SIN(VA*KA))
  171. 1690 XB=F*(COS(VB*KA)):YB=F*(SIN(VB*KA))
  172. 1700 XC=G*(COS(VC*KA)):YC=G*(SIN(VC*KA))
  173. 1710 XD=H*(COS(VD*KA)):YD=H*(SIN(VD*KA))
  174. 1720 XT=XA+XB+XC+XD:YT=YA+YB+YC+YD:REM ADD VECTORS
  175. 1730 MA=SQR((XT*XT)+(YT*YT))
  176. 1740 PRINT:PRINT "POLAR INPUT VECTOR LENGTH";MA
  177. 1750 PRINT:PRINT
  178. 1760 GOSUB 360:PRINT:GOTO 1370
  179. 1770 REM CLS
  180. 1780 REM DAVE RILEY  MARSHFIELD, MASS.  DATA 617-837-2880
  181. 1790 REM LINE PRINTER OUTPUT OF SPACE VECTORS BETWEEN ANY TWO RADIAL HEADINGS
  182. 1800 REM SET 'M' IN FOR M= ? TO ? STEP WHATEVER AMOUNT OF DEGREES
  183. 1810 REM RE-MAKE LINES WITH SA= SB= ETC FOR YOUR OWN PARAMETERS WHERE FIRST
  184. 1820 REM NUMBER IS DISTANCE IN DEGREES FROM ARRAY CENTER TO TOWER #.
  185. 1830 REM SECOND NUMBER IN LINE IS AZIMUTH HEADING FROM CENTR ARRAY THROUGH
  186. 1840 REM TOWER #.
  187. 1850 KA=.017453 : KB=57.29583 :REM RADIAN/DEGREE CONVERSION
  188. 1860 PRINT:PRINT:PRINT
  189. 1870 PRINT"   LINE PRINTER OUTPUT OF MONITOR RADIAL AND FIELD":PRINT
  190. 1880 INPUT "                  TOWER #1 PHASE";A
  191. 1890 INPUT "                  TOWER #2 PHASE";B
  192. 1900 INPUT "                  TOWER #3 PHASE";C
  193. 1910 INPUT "                  TOWER #4 PHASE";D
  194. 1920 PRINT
  195. 1930 INPUT "                  TOWER #1 FIELD";E
  196. 1940 INPUT "                  TOWER #2 FIELD";F
  197. 1950 INPUT "                  TOWER #3 FIELD";G
  198. 1960 INPUT "                  TOWER #4 FIELD";H
  199. 1970 LPRINT:LPRINT
  200. 1980 LPRINT A"/"E
  201. 1990 LPRINT B"/"F
  202. 2000 LPRINT C"/"G
  203. 2010 LPRINT D"/"H
  204. 2020 LPRINT
  205. 2030 LPRINT "RADIAL  -  FIELD"
  206. 2040 FOR M=0 TO 359 STEP 10 :REM SET START AND STOP OF RUN PLUS INCREMENT
  207. 2050 SA=((150*KA)*COS((130-M)*KA))*KB:REM 150 IS DIST IN DEGREES FROM CENTER
  208. 2060 SB=((50*KA)*COS((130-M)*KA))*KB:REM 130 IS HEADING FROM CENTER TO TOWER
  209. 2070 SC=((50*KA)*COS((310-M)*KA))*KB
  210. 2080 SD=((150*KA)*COS((310-M)*KA))*KB
  211. 2090 VA=SA+A : VB=SB+B : VC=SC+C : VD=SD+D
  212. 2100 XA=E*(COS(VA*KA)):YA=E*(SIN(VA*KA))
  213. 2110 XB=F*(COS(VB*KA)):YB=F*(SIN(VB*KA))
  214. 2120 XC=G*(COS(VC*KA)):YC=G*(SIN(VC*KA))
  215. 2130 XD=H*(COS(VD*KA)):YD=H*(SIN(VD*KA))
  216. 2140 XT=XA+XB+XC+XD:YT=YA+YB+YC+YD
  217. 2150 MA=SQR((XT*XT)+(YT*YT))
  218. 2160 LPRINT USING "###.###";M,MA
  219. 2170 NEXT M
  220. 2180 PRINT:PRINT:PRINT:PRINT
  221. 2190 PRINT "                WANT TO RE-RUN WITH A CHANGED INPUT ?"
  222. 2200 PRINT "              TYPE Y FOR YES ELSE ANY KEY FOR MAIN MENU"
  223. 2210 PRINT:PRINT
  224. 2220 R$=INKEY$:IF R$="" THEN 2220
  225. 2230 IF R$="Y" THEN 2270
  226. 2240 IF R$="y" THEN 2270
  227. 2250 GOTO 20
  228. 2260 PRINT:PRINT
  229. 2270 PRINT"        CHANGE ANY A THROUGH H VALUE TO DESIRED PARAMETER."
  230. 2280 PRINT"        AFTER BASIC 'OK' PROMPT TYPE LIKE 'A=-140'and (ENTER)."
  231. 2290 PRINT"        AFTER SECOND BASIC PROMPT, TYPE 'CONT' and (ENTER).
  232. 2300 PRINT:PRINT
  233. 2310 STOP
  234. 2320 GOTO 1970
  235. 3000 REM SYSOP HELPS:
  236. 3010 REM INPLACE OF INKEY YOU MAY HAVE TO USE     INPUT FOR
  237. 3020 REM NUMERIC AND ADD INPUT R$:R$=LEFT$(R$,1) IN LINE 2220
  238. 3030 REM INPLACE OF R$=INKEY$....DEPENDS ON YOUR BASIC THIS WAS
  239. 3040 REM DONE IN GW BASIC (ONE OF THE IBM-ONLY BASICS THAT IS
  240. 3050 REM PRETTY MUCH TRANSPORTABLE).
  241.